140 REM ***************
150 REM *   TINYLOC   *
151 REM * JUN,10 2024 *
152 REM *   IK2PIH    *
153 REM ***************
170 PRINT
175 PRINT "--------------"
180 PRINT "IK2PIH TINYLOC"
185 PRINT "--------------"
186 PRINT
190 PRINT "LON/LAT TO LOCATOR"
195 PRINT
196 INPUT "LON(E/W)? (E=0;W=1) " I
197 IF I<0 GOSUB 950;GOTO 196
198 IF I>1 GOSUB 950;GOTO 196
200 INPUT "LON(DEG)? (  0;179) " L
201 IF L<0 GOSUB 950;GOTO 200
202 IF L>179 GOSUB 950;GOTO 200
205 INPUT "LON(MIN)? (  0; 59) " M
206 IF M<0 GOSUB 950;GOTO 205
207 IF M>59 GOSUB 950;GOTO 205
210 PRINT
211 INPUT "LAT(N/S)? (N=0;S=1) " J
212 IF J<0 GOSUB 950;GOTO 211
213 IF J>1 GOSUB 950;GOTO 211
215 INPUT "LAT(DEG)? (  0; 89) " N
216 IF N<0 GOSUB 950;GOTO 215
217 IF N>89 GOSUB 950;GOTO 215
220 INPUT "LAT(MIN)? (  0; 59) " O
221 IF O<0 GOSUB 950;GOTO 220
222 IF O>59 GOSUB 950;GOTO 220
225 INPUT "LAT(SEC)? (  0; 59) " S
226 IF S<0 GOSUB 950;GOTO 225
227 IF S>59 GOSUB 950;GOTO 225
230 REM * CONVERT TO MINS *
231 IF I=0 LET K=((180+L)*60)+M
232 IF I=1 LET K=((180-L)*60)-M
233 IF J=0 LET W=((90+N)*60)+O
234 IF J=1 LET W=((90-N)*60)-O
235 IF J=0 LET H=S
236 IF J=1 LET H=0-S
300 LET A=K/1200
305 LET B=W/600
310 LET C=((K/60)-(A*20))/2
315 LET D=(W/60)-(B*10)
320 LET E=(K-(A*1200)-(C*120))/5
325 LET F=(((W-(B*600)-(D*60))*60)+H)/150
330 REM * PRINT LOC *
335 PRINT
340 PRINT "LOC: ",
355 GOSUB 900+A
365 GOSUB 900+B
375 GOSUB 800+C
385 GOSUB 800+D
395 GOSUB 900+E
405 GOSUB 900+F
406 PRINT
407 INPUT "CONTINUE? (0=YES, 1=NO) " X
408 IF X<0 GOSUB 950;GOTO 407
409 IF X>1 GOSUB 950;GOTO 407
410 IF X=0 GOTO 170
415 PRINT "BYE!"
420 STOP
798 REM
799 REM * PRINT 0-9 *
800 PRINT "0",;RETURN
801 PRINT "1",;RETURN
802 PRINT "2",;RETURN
803 PRINT "3",;RETURN
804 PRINT "4",;RETURN
805 PRINT "5",;RETURN
806 PRINT "6",;RETURN
807 PRINT "7",;RETURN
808 PRINT "8",;RETURN
809 PRINT "9",;RETURN
898 REM
899 REM * PRINT A-X *
900 PRINT "A",;RETURN
901 PRINT "B",;RETURN
902 PRINT "C",;RETURN
903 PRINT "D",;RETURN
904 PRINT "E",;RETURN
905 PRINT "F",;RETURN
906 PRINT "G",;RETURN
907 PRINT "H",;RETURN
908 PRINT "I",;RETURN
909 PRINT "J",;RETURN
910 PRINT "K",;RETURN
911 PRINT "L",;RETURN
912 PRINT "M",;RETURN
913 PRINT "N",;RETURN
914 PRINT "O",;RETURN
915 PRINT "P",;RETURN
916 PRINT "Q",;RETURN
917 PRINT "R",;RETURN
918 PRINT "S",;RETURN
919 PRINT "T",;RETURN
920 PRINT "U",;RETURN
921 PRINT "V",;RETURN
922 PRINT "W",;RETURN
923 PRINT "X",;RETURN
948 REM
949 REM * ERR MSG *
950 PRINT "WRONG INPUT!"
955 PRINT
960 RETURN